apply plugin: 'com.android.application'

repositories {
    ivy {
        url 'https://download.sonatype.com'
        layout 'pattern', {
            ivy '[module]-ivy.xml'
            artifact '[organisation]/[module]-[revision](.[ext])'
        }
    }
}

configurations {
    iq
}

android {
    compileSdkVersion 25
    buildToolsVersion "25.0.2"
    defaultConfig {
        applicationId "example.sonatype.org.iqgradletesting"
        minSdkVersion 15
        targetSdkVersion 25
        versionCode 1
        versionName "1.0"
        testInstrumentationRunner "android.support.test.runner.AndroidJUnitRunner"
    }
    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
        }
    }
}

dependencies {
    compile fileTree(dir: 'libs', include: ['*.jar'])
    androidTestCompile('com.android.support.test.espresso:espresso-core:2.2.2', {
        exclude group: 'com.android.support', module: 'support-annotations'
    })
    compile 'com.android.support:appcompat-v7:25.2.0'
    compile 'com.android.support.constraint:constraint-layout:1.0.2'
    compile 'com.android.support:design:25.2.0'
    testCompile 'junit:junit:4.12'
//    iq group: 'clm/scanner', name: 'nexus-iq-cli', version: '1.26.0-01'
    iq fileTree(dir: "${rootProject.projectDir}/iqLibs", include: '*.jar')
}

ext.iqScanDir = 'build/lib'
task copyCompileDependencies(type: Copy) {
    into iqScanDir
    from configurations.compile
}

task iqScan(type: JavaExec) {
    classpath = files(configurations.iq.asPath)

    main = 'com.sonatype.insight.scan.cli.PolicyEvaluatorCli'

    // arguments to pass to the IQ CLI
    args '-s', 'http://localhost:8070',
            '-i', 'app',
            '-a', 'admin:admin123',
            iqScanDir
}
iqScan.dependsOn 'copyCompileDependencies'